[Çözüldü] Office365 online Exchange üzerinde vba kodu çalıştırma?

Bu outlook uygulaması için paylaşılan kodların hemen hemen hepsi tek bir domain haricinde uyarı verecek şekilde yazılmış. Çalıştığım yer grup firması olduğu için ve birçok domaine sahip olduğu için vba kodunu sizlerle paylaşmak istedim. İhtiyacı olan arkadaşlar buradan alabilirler.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim recips As Outlook.Recipients
Dim recip As Outlook.Recipient
Dim pa As Outlook.PropertyAccessor
Dim prompt As String
Dim strMsg As String
Dim Address As String
Dim lLen

Const PR_SMTP_ADDRESS As String = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"

Set recips = Item.Recipients
For Each recip In recips
Set pa = recip.PropertyAccessor

Address = LCase(pa.GetProperty(PR_SMTP_ADDRESS))
lLen = Len(Address) - InStrRev(Address, "@")

Select Case Right(Address, lLen)
Case "domain1.com", "domain2.net", "domain3.org"

Case Else ' remove case else line to be warned when sending to the addresses
strMsg = strMsg & " " & Address & vbNewLine
End Select
Next

If strMsg <> "" Then
prompt = "This email will be sent outside of the company to:" & vbNewLine & strMsg & vbNewLine & "Please check recipient address." & vbNewLine & vbNewLine & "Do you still wish to send?"
If MsgBox(prompt, vbYesNo + vbExclamation + vbMsgBoxSetForeground, "Check Address") = vbNo Then
Cancel = True
End If
End If

End Sub

Koddaki 
Case "domain1.com", "domain2.net", "domain3.org"
satırına istediğiniz kadar domain ekleyebilirsiniz. Yazdığınız domain haricinde bir mail adresine gönderim yapıldığında uyarı verecektir.

Exchange üzerinde mailtips için böyle bir özellik var ama uyarı ekranı yok, yani bu yeterli olmalı aslında.

Aktif: Set-OrganizationConfig –MailTipsExternalRecipientsTipsEnabled $True
Pasif: Set-OrganizationConfig –MailTipsExternalRecipientsTipsEnabled $False