Office 2003 Sp3 User Information Script Hk.

Alper Aykut

(@alperaykut)

Gönderiler: 259

Honorable Member

Konu başlatıcı

Merhaba, Domain Ortamında bulunan Clientlarda Microsoft Office 2003 Sp3 Yüklü .Office Uygulamlarında Tool/Options/User İnformation bölümünde Tüm Clientlarda Bilgi Sistemleri şeklinde gozukuyor.Olmasını istediğim ise Clientlarda "User İnformation" kısmında "Bilgi sistemleri" olarak gozuken kısımların Client'ta Domain User ile login olan kullanıcı kim ise o kullanıcının İsminin Binary Değeriğini Aşagıdaki kimi Regedit'e yazmasını Officedeki User İnformation kısmını değiştirebilcek bir Script yazmak için hangi adımları takip etmeliyiz.

Regeditte Goruldu şeklinde

HKEY_CURRENT_USER\Software\Microsoft\Office\11.0\Common\UserInfo

ValueName : User Name :

Value Data : Bilgi Sistemleri Binary değeri ile yazılmıs.

Valuename : User İnitals

ValueData: B.S ( Baş Harfleri Binary Değeri ile yazılmıs )

Teşekkürler.

Gönderildi : 11/11/2010 16:50

CozumPark

(@cozumpark)

Gönderiler: 16307

Illustrious Member Yönetici

merhabalar,

aşağıdaki kodu denermisiniz yapması gerekiyor ;

Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("Wscript.Shell") 

strUsername = oShell.ExpandEnvironmentStrings("%USERNAME%")

On Error Resume Next 

'Convert strUsername to HEX
For i = 1 to Len(strUsername)
 strUsernameHex = strUsernameHex & "," & Hex(Asc(Mid(strUsername, i, 1))) & ",00"
Next

strUsernameHex = Right(strUsernameHex, Len(strUsernameHex) -1)
strUsernameHex = strUsernameHex & ",00,00"

'Create temporary registry file
Const OverwriteIfExist = -1
Const FailIfExist      = 0
Const OpenAsASCII   =  0
Const OpenAsUnicode = -1
Const OpenAsDefault    = -2
sTmpFile = oShell.ExpandEnvironmentStrings("%TEMP%") & "\JBKBUserInfo.reg"
Set fFile = oFSO.CreateTextFile(sTmpFile, OverwriteIfExist, OpenAsASCII)

'Writes to registry file 
fFile.WriteLine "Windows Registry Editor Version 5.00"
fFile.WriteLine
fFile.WriteLine "[HKEY_CURRENT_USER\Software\Microsoft\Office\11.0\Common\UserInfo]"
fFile.WriteLine """UserName""=hex:" & strUsernameHex
fFile.Close

'Set User Name for Office 2003
oShell.Run "regedit /s " & sTmpFile, 0, True

'Delete the temporary registry file
oFSO.DeleteFile sTmpFile

'Set User Name for Office 2007
strRegKey = "HKEY_CURRENT_USER\Software\Microsoft\Office\Common\UserInfo\UserName"
strModify = oShell.RegWrite(strRegKey,strUsername, "REG_SZ")
strModify = null
WScript.Quit

ikinci bir script ki işlemi bitirdikten sonra office tekrar açılınca bir isim girilmesi konusunda bilgi ekranı getirir ;

'resets office 2003 userinfo and user intials to blank. On next office start user is prompted to enter them 
on error resume next

Set WSHShell = Wscript.CreateObject("Wscript.Shell")

wshshell.regwrite "HKCU\Software\Microsoft\Office\11.0\Common\UserInfo\Username",CLng(&H00),"REG_BINARY"

wshshell.regwrite "HKCU\Software\Microsoft\Office\11.0\Common\UserInfo\UserInitials",CLng(&H00),"REG_BINARY"